home *** CD-ROM | disk | FTP | other *** search
/ TPUG - Toronto PET Users Group / TPUG Users Group CD / TPUG Users Group CD.iso / AMIGA / AMICUS / AMICUS15.ADF / PopCLI2 / WBC.a < prev    next >
Text File  |  1988-04-20  |  7KB  |  297 lines
  1.     section    text,CODE
  2. * C initial startup procedure under AmigaDOS
  3. * 
  4. * Requirements:
  5.  
  6.     INCLUDE    "exec/types.i"
  7.     INCLUDE "exec/alerts.i"
  8.     INCLUDE "exec/nodes.i"
  9.     INCLUDE "exec/lists.i"
  10.     INCLUDE "exec/ports.i"
  11.     INCLUDE "exec/libraries.i"
  12.     INCLUDE "exec/tasks.i"
  13.     INCLUDE "libraries/dos.i"
  14.     INCLUDE "libraries/dosextens.i"
  15.     INCLUDE "workbench/startup.i"
  16.  
  17. ; some usefull macros:
  18. xlib    macro
  19.     xref    _LVO\1
  20.     endm
  21.  
  22. callsys    macro
  23.     CALLLIB    _LVO\1
  24.     endm
  25.     
  26.  
  27.     xdef    _XCEXIT            * exit(code) is standard way to leave C.
  28.     xdef    _HandlerInterface
  29.  
  30.     xref    _LinkerDB        * linker defined base value
  31.  
  32.     xref    _Debug
  33.     xref    __main            * Name of C program to start with.
  34.     xref    _MemCleanup
  35.     xref    _AbsExecBase
  36.     xref    _FindTask
  37.     xref    _DOSBase
  38.     xref    _MathBase
  39.     xref    _MathTransBase
  40.         xref    _myhandler
  41.  
  42.     xlib    Alert
  43.     xlib    FindTask
  44.     xlib    Forbid
  45.     xlib    GetMsg
  46.     xlib    OpenLibrary
  47.     xlib    CloseLibrary
  48.     xlib    ReplyMsg
  49.     xlib    Wait
  50.     xlib    WaitPort
  51.     xlib    Open
  52.     xlib    Close
  53.     xlib    CurrentDir
  54.  
  55. start:
  56.     move.l    d0,dosCmdLen
  57.     move.l    a0,dosCmdBuf
  58.     move.l    a7,d0            ; save old stack ptr
  59.     movem.l    d1-d6/a0-a6,-(a7)
  60.     move.l    d0,a5
  61.     move.l    _AbsExecBase,a6
  62.     move.l    a6,_SysBase
  63.     move.l    a7,__StackPtr        * Save stack ptr
  64.     clr.l    _WBenchMsg
  65.  
  66. ;------ get the address of our task
  67.     suba.l    a1,a1
  68.     callsys    FindTask
  69.     move.l    d0,a4
  70.  
  71. ;------ are we running as a son of Workbench?
  72.     move.l    pr_CurrentDir(A4),_curdir
  73.     tst.l    pr_CLI(A4)
  74.     beq    fromWorkbench
  75.  
  76. ;=======================================================================
  77. ;====== CLI Startup Code ===============================================
  78. ;=======================================================================
  79.  
  80. fromCLI:
  81.     move.l    a5,D0        ; get top of stack
  82.     sub.l    4(a5),D0    ; compute bottom 
  83.     move.l    D0,__base    ; save for stack checking
  84. ;------    attempt to open DOS library:
  85.     bsr    openDOS
  86.  
  87. ;------ find command name:
  88.     move.l    #start,a0
  89.     clr.l    -(sp)
  90.     jsr    _FindTask
  91.     addq.l    #4,sp
  92.     move.l    d0,a0
  93.     move.l    pr_CLI(a0),a0
  94.     add.l   a0,a0        ; bcpl pointer conversion
  95.     add.l   a0,a0
  96.     move.l    cli_CommandName(a0),a1
  97.     add.l   a1,a1        ; bcpl pointer conversion
  98.     add.l   a1,a1
  99.  
  100. ;------    collect parameters:
  101.     move.l    dosCmdLen,d0        ; get command line length
  102.     move.l    a1,__ProgramName
  103.     addq.l    #1,d0            ; allow for space after command    
  104.  
  105.     clr.w    -(A7)            ; set null terminator for command line
  106.     addq.l    #1,D0            ; force to even number of bytes
  107.     andi.w    #$fffe,D0        ;(round up)
  108.     sub.l    D0,A7            ; make room on stack for command line
  109.     subq.l    #2,D0
  110.     clr.w    0(A7,D0)
  111.  
  112. ;------ copy command line onto stack
  113.     move.l    dosCmdLen,d0        ; get command line length
  114.     move.l    dosCmdBuf,a0
  115.     move.l    d0,d2
  116.     subq.l    #1,d0
  117.  
  118. copy_line:
  119.     move.b    0(A0,D0.W),0(A7,D2.W)    ; copy command line to stack
  120.     subq.l    #1,d2
  121.     dbf    d0,copy_line
  122.     move.b    #' ',0(a7,d2.w)        ; add space between command and parms
  123.     subq.l    #1,d2
  124.  
  125. copy_cmd:
  126.     move.l    A7,A1
  127.     move.l    A1,-(A7)        ; push command line address
  128.     bra    goto_main                * call C entrypoint
  129.  
  130. ;=======================================================================
  131. ;====== Workbench Startup Code =========================================
  132. ;=======================================================================
  133.  
  134. fromWorkbench:
  135.  
  136.     move.l    TC_SPLOWER(a4),__base    ; set base of stack
  137. ;------ open the DOS library:
  138.     bsr    openDOS
  139.  
  140. ;------ we are now set up.  wait for a message from our starter
  141.     bsr    waitmsg
  142.     move.l    d0,_WBenchMsg
  143.     move.l    d0,-(SP)
  144. ;
  145.     move.l    d0,a2            ; get first argument
  146.     move.l    sm_ArgList(a2),d0
  147.     beq.s    do_cons
  148.     move.l    _DOSBase,a6
  149.     move.l    d0,a0
  150.     move.l    wa_Lock(a0),d1
  151.     move.l    d1,_curdir
  152.     callsys    CurrentDir
  153. do_cons:
  154.     move.l    sm_ToolWindow(a2),d1    ; get the window argument
  155.     beq.s    do_main
  156.     move.l    #MODE_OLDFILE,d2
  157.     callsys    Open
  158.     move.l    d0,stdin
  159.     beq.s    do_main
  160.     lsl.l    #2,d0
  161.     move.l    d0,a0
  162.     move.l    fh_Type(a0),pr_ConsoleTask(A4)
  163. do_main:
  164.     move.l    _WBenchMsg,a0        ; get address of workbench message
  165.     move.l    sm_ArgList(a0),a0    ; get address of arguments
  166.     move.l    wa_Name(a0),__ProgramName    ; get name of program
  167.     moveq    #0,d0
  168.     move.l    d0,-(A7)
  169.  
  170. goto_main:
  171.     lea    _LinkerDB,a6        ; load base register
  172.     jsr    __main                * call C entrypoint
  173.     moveq.l    #0,d0            ; set successful status
  174.     bra.s    exit2
  175. ;
  176.  
  177. _XCEXIT:
  178.     move.l    4(SP),d0    ; extract return code
  179. exit2:
  180.     move.l    d0,-(a7)
  181.     move.l    _SysBase,a6
  182.     move.l    _DOSBase,a1
  183.     callsys    CloseLibrary        ; close Dos library
  184. done_1b:
  185. ;------ if we ran from CLI, skip workbench cleanup:
  186.     tst.l    _WBenchMsg
  187.     beq.s    exitToDOS
  188.     move.l    _console_dev,d1
  189.     beq.s    done_2
  190.     callsys    Close
  191. done_2:
  192.     move.l    stdin,d1
  193.     beq.s    done_4
  194.     callsys    Close
  195. done_4:
  196.  
  197. ;------ return the startup message to our parent
  198. ;    we forbid so workbench can't UnLoadSeg() us
  199. ;    before we are done:
  200.     move.l    _AbsExecBase,A6
  201.     callsys Forbid
  202.     move.l    _WBenchMsg,a1
  203.     callsys    ReplyMsg
  204.  
  205. ;------ this rts sends us back to DOS:
  206. exitToDOS:
  207.     MOVE.L    (A7)+,D0
  208.     movea.l  __StackPtr,SP        * restore stack ptr
  209.     movem.l    (a7)+,d1-d6/a0-a6
  210.     rts                * and exit
  211.  
  212. ;-----------------------------------------------------------------------
  213. noDOS:
  214.         ALERT    (AG_OpenLib!AO_DOSLib)
  215.         moveq.l    #100,d0
  216.         bra    exit2
  217.  
  218.  
  219. ;-----------------------------------------------------------------------
  220. ; This routine gets the message that workbench will send to us
  221. ; called with task id in A4
  222.  
  223. waitmsg:
  224.         lea    pr_MsgPort(A4),a0      * our process base
  225.         callsys    WaitPort
  226.         lea    pr_MsgPort(A4),a0      * our process base
  227.         callsys GetMsg
  228.         rts
  229.  
  230. ;-----------------------------------------------------------------------
  231. ;  Open the DOS library:
  232.  
  233. openDOS
  234.         lea    DOSName,A1
  235.         moveq.l    #0,D0
  236.         callsys OpenLibrary
  237.         move.l    D0,_DOSBase
  238.         beq    noDOS
  239.         rts
  240.  
  241. *************************************************************************
  242. *   HandlerInterface()
  243. *
  244. *   This code is needed to convert the calling sequence performed by
  245. *   the input.task for the input stream management into something
  246. *   that a C program can understand.
  247. *
  248. *   This routine expects a pointer to an InputEvent in A0, a pointer
  249. *   to a data area in A1.  These values are transferred to the stack
  250. *   in the order that a C program would need to find them.  Since the
  251. *   actual handler is written in C, this works out fine. 
  252. *
  253. *   Author: Rob Peck, 12/1/85
  254. *
  255.  
  256. _HandlerInterface:
  257.     movem.L    A0/A1,-(A7)
  258.     jsr    _myhandler
  259.     addq.L    #8,A7
  260.     rts
  261.  
  262.     section    "__MERGED",DATA
  263. ;
  264.     XDEF    _NULL,_SysBase,_LoadAddress,_console_dev,_WBenchMsg
  265.     XDEF    _curdir,__mbase,__mnext,__msize,__tsize
  266.     XDEF    __oserr,__OSERR,__FPERR,__SIGFPE,__ONERR,__ONEXIT,__ONBREAK
  267.     XDEF    __SIGINT,__ECS
  268.     XDEF    __ProgramName,__StackPtr,__base
  269. ;
  270. _NULL        dc.l    0        ;
  271. __base        dc.l    0        ; base of stack
  272. __mbase        dc.l    0        ; base of memory pool
  273. __mnext        dc.l    0        ; next available memory location
  274. __msize        dc.l    0        ; size of memory pool
  275. __tsize        dc.l    0        ; total size?
  276. __oserr        equ    *
  277. __OSERR        dc.l    0
  278. __FPERR        dc.l    0
  279. __SIGFPE    dc.l    0
  280. __SIGINT    dc.l    0
  281. __ONERR        dc.l    0
  282. __ONEXIT    dc.l    0
  283. __ONBREAK    dc.l    0
  284. __ECS        dc.l    0        ; extended character set flag
  285. _curdir        dc.l    0
  286. _console_dev    dc.l    0
  287. _SysBase    dc.l    0
  288. _LoadAddress    dc.l    0            ; program load address
  289. _WBenchMsg    dc.l    0
  290. __StackPtr    dc.l    0
  291. dosCmdLen    dc.l    0
  292. dosCmdBuf    dc.l    0
  293. stdin        dc.l    0
  294. __ProgramName    dc.l    0
  295. DOSName     DOSNAME
  296.  
  297.     END